;; Modules to import to access variables used.
(define-module (corpo system)
  #:use-module (gnu)
  #:use-module (gnu services guix)
  #:use-module (nongnu packages linux)
  #:use-module (nongnu system linux-initrd)
  #:use-module (nongnu packages nvidia)
  #:use-module (nongnu services nvidia)
  #:use-module (corpo home))

(use-service-modules linux guix desktop pm audio 
		     networking dbus xorg avahi spice)
(use-package-modules linux audio libusb wm fonts
		     freedesktop vim cryptsetup)

(operating-system
  (locale "en_GB.utf8")
  (timezone "Europe/London")
  (keyboard-layout (keyboard-layout "gb"))
  (host-name "corpo")

  ;; Users ('root' is implicit).
  (users (cons* (user-account
                  (name "worker")
                  (comment "worker")
		  (password (crypt "worker" "$6$abc"))
                  (group "users")
                  (home-directory "/home/corpo")
                  (supplementary-groups '("wheel" "netdev" "audio" "video")))
                %base-user-accounts))

  (bootloader (bootloader-configuration
                (bootloader grub-bootloader)
                (targets '("/dev/vda"))
                (terminal-outputs '(console))))

  (file-systems (cons (file-system
                        (mount-point "/")
                        (device "/dev/vda1")
                        (type "ext4"))
                      %base-file-systems))

  ;; Non-free
  (kernel linux)
  (kernel-arguments '("modprobe.blacklist=noveau"
		      ;"nvidia_drm.modeset=1"
		      "quiet"))
  (firmware (list linux-firmware))
  (initrd microcode-initrd)

  ;; Services (system-wide)
  (services (append
	      (modify-services %base-services
			       (delete login-service-type)
			       (delete mingetty-service-type)
			       (delete console-font-service-type)
			       ;; Add non-free substitutes
			       (guix-service-type
				 config =>
				 (guix-configuration
				   (inherit config)
				   (substitute-urls
				     (append (list "https://substitutes.nonguix.org")
					     %default-substitute-urls))
				     (authorized-keys
				       (append (list (local-file "files/nonguix-signing-key.pub"))
					       %default-authorized-guix-keys)))))
	      (list 
	      ;; NVIDIA
	      ;(service nvidia-service-type)
              ;(service kernel-module-loader-service-type 
		       ;'("nvidia"))
	      ;; systemd dependencies
	      (service elogind-service-type)

	      ;; spice for VMs
	      (service spice-vdagent-service-type)

	      ;; PAM and login
	      (service greetd-service-type
		       (greetd-configuration
			 (greeter-supplementary-groups (list "video" "input"))
                         (terminals
			   (list
			     (greetd-terminal-configuration
			       (terminal-vt "1")
			       (terminal-switch #t))
			     (greetd-terminal-configuration (terminal-vt "2"))
			     (greetd-terminal-configuration (terminal-vt "3"))))))

	      (service console-font-service-type
		       (map (lambda (tty)
			    (cons tty (file-append
					font-terminus
					"/share/consolefonts/ter-132n")))
			    '("tty1" "tty2" "tty3")))

	      (service screen-locker-service-type
		       (screen-locker-configuration
			 (name "swaylock")
			 (program (file-append swaylock "/bin/swaylock"))
			 (using-pam? #t)
			 (using-setuid? #t)))

	      ;; Networking
	      ;(service network-manager-service-type)
	      (service wpa-supplicant-service-type)
	      (service static-networking-service-type
	      	       (list (static-networking
	      		       (addresses
	      			 (list (network-address
	      				 (device "eth0")
	      				 (value "10.0.2.15/24"))))
	      		       (routes
	      			 (list (network-route
	      				  (destination "default")
	      				  (gateway "10.0.2.2"))))
	      		       (name-servers '("208.67.222.222")))))
	      ;; dbus
	      (service avahi-service-type)
	      (service udisks-service-type)
	      (service accountsservice-service-type)
	      (service colord-service-type)
	      (service polkit-service-type)
	      (service dbus-root-service-type)

	      ;; Cleanup stayle font cache
              fontconfig-file-system-service

	      ;; Power and thermals
	      (service thermald-service-type)
	      (service power-profiles-daemon-service-type)

	      ;; Xwayland
	      (service x11-socket-directory-service-type)

	      ;; Time
	      (service ntp-service-type)

	      ;; udev
	      (udev-rules-service 'pipewire-add-udev-rules pipewire)
	      
	      ;; corpo home
	      (service guix-home-service-type
		       `(("worker" ,corpo-home-environment))))))

  ;; Packages (system-wide) 
  (packages (cons* vim
		   cryptsetup
		   strace
		   %base-packages)))